Perl 펄] EXIF 정보 읽기, 디카 촬영 정보 출력 소스; Exif Info Dump

#!/usr/bin/perl
use strict; use warnings;

  die "Input photo filename...\n" if ($#ARGV == -1);
  die "Not a valid file...\n" if not (-f $ARGV[0]);

  use Image::ExifTool;

  my $exifTool = new Image::ExifTool;
  $exifTool->Options(Unknown => 1);
  my $info = $exifTool->ImageInfo($ARGV[0]);
  my $group = '';
  my $tag;

  foreach $tag ($exifTool->GetFoundTags('Group0')) {
    if ($group ne $exifTool->GetGroup($tag)) {
      $group = $exifTool->GetGroup($tag);
      print "---- $group ----\n";
    }

    my $val = $info->{$tag};

    if (ref $val eq 'SCALAR') {
      if ($$val =~ /^Binary data/) {
        $val = "($$val)";
      } else {
        my $len = length($$val);
        $val = "(Binary data $len bytes)";
      }
    }

    $val = stringToHex($val) if (!isPrintableString($val));
    printf("%-32s : %s\n", $exifTool->GetDescription($tag), $val);
  }




sub isPrintableString {
  my @a = unpack "C*", $_[0]; # 문자열을, 1바이트씩 분리하여 배열로 만들기

  foreach (@a) {
    next if ($_ == 0x0A || $_ == 0x0D || $_ == 0x09);
    return 0 if ($_ < 0x20 || $_ > 0x7E); # 키보드로 입력할 수 없는 문자일 경우는 거짓(false) 반환
  }
  return 1; # 그밖의 경우는 참(true) 반환
}


sub stringToHex {
  my @a = unpack "C*", $_[0]; # 문자열을, 1바이트씩 분리하여 배열로 만들기
  my $s = "";

  foreach (@a) {
    $s .= sprintf("%02X ", $_);
  }
  return $s;
}