Perl 펄] 디카 메타 정보를, JPG, RAW (NEF) 파일명으로 변경 유틸리티; Exif to Filename

#!/usr/bin/perl
use strict; use warnings;

# v0.5d

use Image::ExifTool;
use File::Basename;
use Term::ReadKey; # getAkey

  my $exifTool = new Image::ExifTool;


  # 현재 디렉토리의 모든 파일명들을 배열로 저장
  opendir(DIR, ".") or die "$!\n";
  my @items = readdir(DIR);  # @items 라는 배열에, 파일 목록 넣기
  closedir DIR;


  # 기타 변수 선언
  my $all = 0;
  my $choice;




# 본격 작업 시작
# 현재 디렉토리의 사진 파일들을 모두
# Exif 문자열로 리네임

LOOP: foreach (@items) { # 각 파일을 대상으로 하나씩 작업
  my $filename = $_;
  next unless (-f $filename); # 디렉토리면 건너뛰기
  my ($fileNameOnly, $dir, $ext) = fileparse($filename, '\.[^.]*');
  next if ($ext !~ /^\.jpg$|^\.jpeg$|^\.nef$|^\.tif$|^\.tiff$/i); # JPG / RAW 등의 확장자만 대상으로

  my $exif_str = getExif($filename); # 사진 파일의 Exif 정보 읽기
  if (defined $exif_str) { # Exif 정보 있는 파일만 처리
    print "\"$filename\" 를 아래의 파일명으로 바꿀까요? [ y(es)/n(o)/a(ll)/q(uit) ]", "\n"; # 각 파일명 출력
    my $filename_new = $exif_str . lc($ext);
    print $filename_new, "\n";

    for (;;) { # 사용자 허락받은 후 파일명 변경
      if ($all == 1) { $choice = "a"; }
      else { $choice = getAkey(); } # 키보드 입력 받기

      if ($choice =~ /^a/) { $all = 1; }

      if ($choice =~ /^y/ || $all == 1) { # Yes면 변경
        if (-f $filename_new) { warn "같은 파일명이 이미 존재함!\n"; }
        else { rename($filename, $filename_new) or warn "변경 실패!\n"; }
        last;
      }
      elsif ($choice =~ /^n/) { last; } # No 면 다음 파일로 건너뛰기
      elsif ($choice =~ /^q/) { last LOOP; } # LOOP를 완전히 빠져나가라는 의미
    }
    print "\n";
  }

}



# 파일의 Exif 정보를 읽어서, 한줄의 문자열로 요약하여 반환 함수
sub getExif {
  my $info = $exifTool->ImageInfo($_[0]);
  my ($temp, @temp, $s);


  # 카메라 모델명
  $temp = $$info{"Model"};
  return undef if not defined $temp; # 모델명 없으면 에러 반환
  $temp =~ s/[\s]/-/g;
  $s = $temp;


  # 날짜/시간 처리
  @temp = split(/[:\s]/, $$info{"DateTimeOriginal"});
  $s .= " " . $temp[0] . $temp[1] . $temp[2] . "-" . $temp[3] . $temp[4] . $temp[5];


  # 초 단위 이하 처리
  $temp = $$info{"SubSecTimeOriginal"};
  if (defined $temp) {
    $s .= "-" . $temp;
  } else {
    $s .= "-XX";
  }



  # 감도
  # (니콘은 1600보다 높으면, "Hi 3200" 이라고 나오는데, 여기서 숫자만 추출)
  @temp = $$info{"ISO"} =~ /[\d.*]/g;
  $s .= " ISO" . join("", @temp);


  # 초점 거리 (35미리 포맷으로 환산한 초점거리)
  $temp = $$info{"FocalLengthIn35mmFormat"};
  if (defined $temp) {
    $s .= " " . $temp;
  } else {
    $s .= " XX";
  }
  $s .= "mm";


  # 조리개
  $temp  = $$info{"FNumber"};
  $s .= " F" . $temp;


  # 셔터 속도
  $temp = $$info{"ExposureTime"};
  $s .= " S" . $temp;


  # 카메라 수평/수직 방향
  if ($$info{"Orientation"} !~ "Horizontal") {
    $s .= " [V]";
  }


  # 렌즈 스펙
  $temp = $$info{"Lens"};
  if (defined $temp) {
    $s .= " (" . $temp . ")";
  }


  # 모든 슬래시를 하이픈으로 변환. 파일명에는 슬래시(/) 기호 허용 안됨
  $s =~ s/[\/]/-/g;


  return $s;
}


# 키보드에서 영문 딱 1글자만 입력받는 함수 (Enter키 칠 필요 없음)
sub getAkey {
  ReadMode 'cbreak';
  my $key = ReadKey(0);
  print $key; # echo 가 안되어서 억지로 출력
  ReadMode 'normal';

  return lc($key); # 소문자로 변환한 후 반환
}